echo You may Install one of two ways:
echo
echo SMALL install will only install the STARTUP DISK to your 
echo hard drive. You MUST play from floppies. 
echo Approximate hard drive space required:	860K
echo
echo COMPLETE install will install all files to your hard drive.
echo The entire game will be played from a hard drive.
echo Approximate hard drive space required:	5.2 Meg
echo
echo Would you like to install (S)mall, (C)omplete or (E)xit?
pick sce small large Exit2
:small
clear
space %1: 860 NoSpace 
godir %1:\sierra\pq3	CantCreate
echo Copying Startup Files ...
copy %2:vga320.drv
copy %2:std.drv
copy %2:mt32.drv
copy %2:mtblast.drv
copy %2:sndblast.drv
copy %2:ibmps1.drv
copy %2:adl.drv
copy %2:cms.drv
copy %2:ibmkbd.drv
copy %2:tandy3v.drv
copy %2:tandy3vd.drv
copy %2:proaudio.drv
copy %2:vga320bw.drv
copy %2:joystick.drv
copy %2:version
copy %2:scidhuv.exe
copy %2:resource.000 
copy %2:resource.map 
copy %2:resource.cfg
copy %2:install.exe
copy %2:install.hlp
copy %2:install.txt
copy %2:install.scr
copy %2:interp.txt
echo %3 > resource.cfg
copy %2:pq3rs.bat %1:\pq3.bat
copy %2:pq3rs.bat %1:\sierra\pq3.bat
copy %2:pq3.bat
copy %2:sierra.bat
copy %2:21.*
copy %2:129.*
copy %2:133.*
copy %2:12.*
copy %2:50.*
copy %2:56.*
copy %2:57.*
copy %2:594.v56
goto exit
:large
clear
space %1: 5100	NoSpace
godir %1:\sierra\pq3	CantCreate
echo Copying Startup Files ...
copy %2:vga320.drv
copy %2:std.drv
copy %2:mt32.drv
copy %2:mtblast.drv
copy %2:sndblast.drv
copy %2:ibmps1.drv
copy %2:adl.drv
copy %2:cms.drv
copy %2:ibmkbd.drv
copy %2:tandy3v.drv
copy %2:tandy3vd.drv
copy %2:proaudio.drv
copy %2:vga320bw.drv
copy %2:joystick.drv
copy %2:version
copy %2:scidhuv.exe
copy %2:resource.000 
copy %2:resource.map 
copy %2:resource.cfg
copy %2:install.exe
copy %2:install.hlp
copy %2:install.txt
copy %2:install.scr
copy %2:interp.txt
echo %3 > resource.cfg
copy %2:pq3rs.bat %1:\pq3.bat
copy %2:pq3rs.bat %1:\sierra\pq3.bat
copy %2:pq3h.bat pq3.bat
copy %2:sierrah.bat sierra.bat
copy %2:21.*
copy %2:129.*
copy %2:133.*
copy %2:12.*
copy %2:50.*
copy %2:56.*
copy %2:57.*
copy %2:594.v56
echo Copying Game files...
exists %2:resource.001 Please insert the disk labeled "Disk 1" in drive %2:.
copy %2:resource.001
exists %2:resource.002 Please insert the disk labeled "Disk 2" in drive %2:.
copy %2:resource.002
exists %2:resource.003 Please insert the disk labeled "Disk 3" in drive %2:.
copy %2:resource.003
exists %2:resource.004 Please insert the disk labeled "Disk 4" in drive %2:.
copy %2:resource.004
rem exists %2:resource.005 Please insert the disk labeled "Disk 5" in drive %2:.
rem copy %2:resource.005
:exit
clear
echo
echo ˙To play NOW:
echo ˙   Type PQ3 [ENTER].
echo
echo ˙To play LATER:
echo ˙   From the root directory of %1:,
echo ˙   Type PQ3 and press [ENTER].
echo
pause
goto Exit2
:NoSpace
clear
echo
echo There is not enough space on %1: to install Police Quest III!
rem determine which message to bring up.
space %1: 860 NoSmall 
echo 5.2 megabytes of disk space are necessary.
echo
echo SMALL install will only install the STARTUP DISK 
echo to your hard drive. You MUST play from floppies. 
echo SMALL install is recommended, due to insufficient
echo hard drive space.
echo
echo Would you like to install (S)mall or (E)xit?
pick se small Exit2
:NoSmall
alert 860 kilobytes of disk space are necessary.
end
:Exit2
end
:CantCreate
alert Unable to create directory %1:\sierra\pq3
end

